[PATCH 6/6] lei q: Sort threads by date of initial message

[Kyle Meyer <kyle@kyleam.com>]

Now that there is a command for displaying multiple threads, the order
that piem-lei-query--thread returns the threads matters.  When lei-q
is given the --threads option, the threads don't have a clear order,
and --sort and --reverse don't have an effect, so
piem-lei-query--thread must handle the sorting.

Teach piem-lei-query--thread to sort by the date of the root message
in a thread, adding a option to control the direction of this sorting.

It may be better to sort by the latest date within the entire thread.
However, doing so is more expensive, so don't bother until a clear
case is made that it's the better option.
---
 piem-lei.el | 29 ++++++++++++++++++++++++++++-
 1 file changed, 28 insertions(+), 1 deletion(-)

diff --git a/piem-lei.el b/piem-lei.el
index 1c232da2..db922944 100644
--- a/piem-lei.el
+++ b/piem-lei.el
@@ -43,6 +43,13 @@ (defcustom piem-lei-query-initial-input "d:20.days.ago.. "
   :type '(choice (const :tag "None" nil)
                  (string :tag "Query")))
 
+(defcustom piem-lei-query-oldest-thread-first nil
+  "Whether to display older threads before new ones.
+The date and time of the initial message is taken as the age of
+the thread."
+  :package-version '(piem . "0.4.0")
+  :type 'boolean)
+
 \f
 ;;;; Helpers
 
@@ -567,6 +574,20 @@ (defun piem-lei-query--has-descendant (msg1 msg2)
         (setq msg2 (piem-lei-msg-parent msg2)))
       nil)))
 
+(defun piem-lei--msg-time-with-fallback (msg)
+  (or (piem-lei-msg-time msg)
+      ;; The initial message is a ghost.  Use the time from the first
+      ;; child encountered, without making any effort to ensure that
+      ;; it's the sibling with the earliest time.
+      (catch 'stop
+        (let ((children (piem-lei-msg-children msg)))
+          (while children
+            (let ((child (pop children)))
+              (if-let ((time (piem-lei-msg-time child)))
+                  (throw 'stop time)
+                (setq children
+                      (append children (piem-lei-msg-children child))))))))))
+
 (defun piem-lei-query--thread (records)
   "Thread messages in RECORDS.
 
@@ -612,7 +633,13 @@ (defun piem-lei-query--thread (records)
          (unless (piem-lei-msg-parent v)
            (push v roots)))
        thread)
-      (nreverse roots))))
+      (let* ((fn (if piem-lei-query-oldest-thread-first #'not #'identity))
+             (sort-fn
+              (lambda (a b)
+                (funcall fn
+                         (time-less-p (piem-lei--msg-time-with-fallback b)
+                                      (piem-lei--msg-time-with-fallback a))))))
+        (sort roots sort-fn)))))
 
 (defvar piem-lei-query--subject-split-re
   (rx string-start
-- 
2.34.0