discussion and development of piem
 help / color / mirror / code / Atom feed
94b1fa0a24bde02e969bad5903ce383848fb8edf blob 5111 bytes (raw)

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
 
;;; piem-notmuch.el --- Notmuch integration for piem  -*- lexical-binding: t; -*-

;; Copyright (C) 2020-2021  Kyle Meyer

;; Author: Kyle Meyer <kyle@kyleam.com>
;; Keywords: vc, tools
;; Package-Requires: ((emacs "26.3"))

;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this program.  If not, see <https://www.gnu.org/licenses/>.

;;; Commentary:

;; This library provides a minor mode, `piem-notmuch-mode', that
;; modifies `piem' variables to teach functions like `piem-inbox' and
;; `piem-am-ready-mbox' how to extract information from Notmuch
;; buffers.

;;; Code:

(require 'mm-decode)
(require 'notmuch)
(require 'piem)
(require 'subr-x)

(defmacro piem-notmuch--with-current-message (&rest body)
  (declare (indent 0) (debug (body)))
  (let ((rv (make-symbol "rv")))
    `(let (,rv)
       (with-current-notmuch-show-message
        (setq ,rv ,(macroexp-progn body)))
       ,rv)))

(defun piem-notmuch-get-inbox ()
  "Return inbox name from a `notmuch-show-mode' buffer."
  (when (derived-mode-p 'notmuch-show-mode)
    (piem-notmuch--with-current-message
      (piem-inbox-by-header-match))))

(defun piem-notmuch-get-mid ()
  "Return the message ID of a `notmuch-show-mode' buffer."
  (notmuch-show-get-message-id 'bare))

(defun piem-notmuch-known-mid-p (mid)
  "Return non-nil if MID is known to Notmuch.
The message ID should not include Notmuch's \"id:\" prefix or
have surrounding brackets."
  (let ((query (concat "id:" mid)))
    (equal query
           (string-trim-right
            (with-output-to-string
              (with-current-buffer standard-output
                (call-process notmuch-command
                              nil '(t nil) nil
                              "search" "--output=messages" query)))))))

(defun piem-notmuch-mid-to-thread (mid)
  "Return a function that inserts an mbox for MID's thread."
  (when (piem-notmuch-known-mid-p mid)
    (lambda ()
      (call-process notmuch-command
                    nil '(t nil) nil
                    "show" "--format=mbox" "--entire-thread=true"
                    (concat "id:" mid)))))

(defun piem-notmuch-am-ready-mbox ()
  "Return a function that inserts an am-ready mbox.
If the buffer has any MIME parts that look like a patch, use
those parts' contents (in order) as the mbox.  Otherwise, use the
message itself if it looks like a patch."
  (when (derived-mode-p 'notmuch-show-mode)
    (if (string-prefix-p
         "multipart/"
         (plist-get
          (car (plist-get (notmuch-show-get-message-properties)
                          :body))
          :content-type))
        (let (patches)
          (piem-notmuch--with-current-message
            (notmuch-foreach-mime-part
             (lambda (p)
               (and (piem-am-patch-attachment-p
                     (mm-handle-media-type p)
                     (mm-handle-filename p))
                    (with-temp-buffer
                      (mm-display-inline p)
                      (push (buffer-substring-no-properties
                             (point-min) (point-max))
                            patches))))
             (mm-dissect-buffer)))
          (when patches
            (setq patches (nreverse patches))
            (cons (lambda ()
                    (dolist (patch patches)
                      (insert patch)))
                  "mbox")))
      (when (string-match-p piem-patch-subject-re
                            (notmuch-show-get-subject))
        (let ((id (notmuch-show-get-message-id)))
          (lambda ()
            (call-process notmuch-command nil t nil
                          "show" "--format=mbox" id)))))))

;;;###autoload
(define-minor-mode piem-notmuch-mode
  "Toggle Notmuch support for piem.
With a prefix argument ARG, enable piem-notmuch mode if ARG is
positive, and disable it otherwise.  If called from Lisp, enable
the mode if ARG is omitted or nil."
  :global t
  :init-value nil
  (if piem-notmuch-mode
      (progn
        (add-hook 'piem-am-ready-mbox-functions #'piem-notmuch-am-ready-mbox)
        (add-hook 'piem-get-inbox-functions #'piem-notmuch-get-inbox)
        (add-hook 'piem-get-mid-functions #'piem-notmuch-get-mid)
        (add-hook 'piem-mid-to-thread-functions #'piem-notmuch-mid-to-thread))
    (remove-hook 'piem-am-ready-mbox-functions #'piem-notmuch-am-ready-mbox)
    (remove-hook 'piem-get-inbox-functions #'piem-notmuch-get-inbox)
    (remove-hook 'piem-get-mid-functions #'piem-notmuch-get-mid)
    (remove-hook 'piem-mid-to-thread-functions #'piem-notmuch-mid-to-thread)))

;;; piem-notmuch.el ends here
(provide 'piem-notmuch)
debug log:

solving 94b1fa0 ...
found 94b1fa0 in https://inbox.kyleam.com/piem/20210103180912.17404-3-kyle@kyleam.com/
found ff8654c in https://git.kyleam.com/piem/
preparing index
index prepared:
100644 ff8654c17c5a1d0d9ed0b239fe4644bda17c5623	piem-notmuch.el

applying [1/1] https://inbox.kyleam.com/piem/20210103180912.17404-3-kyle@kyleam.com/
diff --git a/piem-notmuch.el b/piem-notmuch.el
index ff8654c..94b1fa0 100644

Checking patch piem-notmuch.el...
Applied patch piem-notmuch.el cleanly.

index at:
100644 94b1fa0a24bde02e969bad5903ce383848fb8edf	piem-notmuch.el

discussion and development of piem

This inbox may be cloned and mirrored by anyone:

	git clone --mirror https://inbox.kyleam.com/piem/0 piem/git/0.git

	# If you have public-inbox 1.1+ installed, you may
	# initialize and index your mirror using the following commands:
	public-inbox-init -V2 piem piem/ https://inbox.kyleam.com/piem \
		piem@inbox.kyleam.com
	public-inbox-index piem

Example config snippet for mirrors.
Newsgroup available over NNTP:
	nntp://news.yhetil.org/yhetil.emacs.piem


code repositories for project(s) associated with this inbox:

	https://git.kyleam.com/piem/

AGPL code for this site: git clone http://ou63pmih66umazou.onion/public-inbox.git