Re: On the road to (GNU) debbugs support, some blockers

[Kyle Meyer <kyle@kyleam.com>]

Jelle Licht writes:

> As mentioned, I use debbugs.el to interact with the issue tracker. [1]
> [...]
> [1]: Not entirely relevant to the issue at hand, but I also have all
> guix-patches messages available and indexed in my local notmuch
> setup. [...]

Because you have the local Notmuch store, perhaps you'd be interested in
debbugs.el visiting the message in Notmuch rather than Gnus.  As I said,
I haven't actually used debbugs.el much, but I stumbled on this in my
config:

  ;; Modified from function in Nicolas Petton's emacs configuration
  ;; (https://gitlab.petton.fr/nico/emacs.d/, 208407f53a)
  (defun km/debbugs-notmuch-select-report (&rest _)
    (require 'debbugs-gnu)
    (let* ((status (debbugs-gnu-current-status))
           (id (cdr (assq 'id status)))
           (merged (cdr (assq 'mergedwith status))))
      (setq merged (if (listp merged) merged (list merged)))
      (unless id
        (user-error "No bug report on the current line"))
      (let ((address (format "%s@debbugs.gnu.org" id))
            (merged-addresses (string-join (mapcar (lambda (id)
                                                     (format "%s@debbugs.gnu.org" id))
                                                   merged)
                                           " ")))
        (notmuch-tree (format "%s %s" address merged-addresses)))))

  (advice-add 'debbugs-gnu-select-report :override
              #'km/debbugs-notmuch-select-report)