discussion and development of piem
 help / color / mirror / code / Atom feed
blob 4afa7479ddd3773241c60c157adaa428f066b1d4 4507 bytes (raw)
name: piem-gnus.el 	 # note: path name is non-authoritative(*)

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
 
;;; piem-gnus.el --- Gnus integration for piem  -*- lexical-binding: t; -*-

;; Copyright (C) 2020  Kyle Meyer

;; Author: Kyle Meyer <kyle@kyleam.com>
;; Keywords: vc, tools
;; Package-Requires: ((emacs "26.3"))

;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this program.  If not, see <https://www.gnu.org/licenses/>.

;;; Commentary:

;; This library provides a minor mode, `piem-gnus-mode', that modifies
;; `piem' variables to teach functions like `piem-inbox' and
;; `piem-am-ready-mbox' how to extract information from Gnus buffers.

;;; Code:

(require 'gnus)
(require 'gnus-sum)
(require 'message)
(require 'piem)

(defgroup piem-gnus nil
  "Gnus integration for piem."
  :group 'piem)

(defun piem-gnus-get-inbox ()
  "Return inbox name from a Gnus article"
  (when (derived-mode-p 'gnus-article-mode 'gnus-summary-mode)
    (with-current-buffer gnus-original-article-buffer
      (piem-inbox-by-header-match))))

(defun piem-gnus-get-mid ()
  "Return the message ID of a Gnus article."
  (when (derived-mode-p 'gnus-article-mode 'gnus-summary-mode)
    (with-current-buffer gnus-original-article-buffer
      (when-let ((mid (message-field-value "Message-ID")))
        (if (string-match (rx string-start (zero-or-more space) "<"
                              (group (one-or-more (not (any ">"))))
                              ">" (zero-or-more space) string-end)
                          mid)
            (match-string 1 mid)
          mid)))))

;; If there is an easy way to generate an mbox for a thread in Gnus, a
;; function for `piem-mid-to-thread-functions' should be defined.

(defun piem-gnus-am-ready-mbox ()
  "Return a function that inserts an am-ready mbox.
If the buffer has any MIME parts that look like a patch, use
those parts' contents (in order) as the mbox.  Otherwise, use the
message itself if it looks like a patch."
  (when (derived-mode-p 'gnus-article-mode 'gnus-summary-mode)
    (cond
     (gnus-article-mime-handles
      (let ((patches
             (delq nil
                   (mapcar (lambda (handle)
                             (and (listp handle)
                                  (member (caar (cdr handle))
                                          '("text/x-diff" "text/x-patch"))
                                  (with-temp-buffer
                                    (mm-display-inline handle)
                                    (buffer-substring-no-properties
                                     (point-min) (point-max)))))
                           gnus-article-mime-handles))))
        (when patches
          (cons (lambda ()
                  (dolist (patch patches)
                    (insert patch)))
                "mbox"))))
     (gnus-article-buffer
      (let ((patch (with-current-buffer gnus-article-buffer
                     (save-restriction
                       (widen)
                       (and (string-match-p piem-patch-subject-re
                                            (message-field-value "subject"))
                            (buffer-substring-no-properties
                             (point-min) (point-max)))))))
        (when patch
          (cons (lambda () (insert patch))
                "mbox")))))))

;;;###autoload
(define-minor-mode piem-gnus-mode
  "Toggle Gnus support for piem.
With a prefix argument ARG, enable piem-gnus mode if ARG is
positive, and disable it otherwise.  If called from Lisp, enable
the mode if ARG is omitted or nil."
  :global t
  :init-value nil
  (if piem-gnus-mode
      (progn
        (add-hook 'piem-am-ready-mbox-functions #'piem-gnus-am-ready-mbox)
        (add-hook 'piem-get-inbox-functions #'piem-gnus-get-inbox)
        (add-hook 'piem-get-mid-functions #'piem-gnus-get-mid))
    (remove-hook 'piem-am-ready-mbox-functions #'piem-gnus-am-ready-mbox)
    (remove-hook 'piem-get-inbox-functions #'piem-gnus-get-inbox)
    (remove-hook 'piem-get-mid-functions #'piem-gnus-get-mid)))

;;; piem-gnus.el ends here
(provide 'piem-gnus)

debug log:

solving 4afa747 ...
found 4afa747 in https://git.kyleam.com/piem/

(*) Git path names are given by the tree(s) the blob belongs to.
    Blobs themselves have no identifier aside from the hash of its contents.^

Code repositories for project(s) associated with this public inbox

	https://git.kyleam.com/piem/

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).