discussion and development of piem
 help / color / mirror / code / Atom feed
blob 2ad4ace6c258397f2a5048aba035300a8a9479c8 7147 bytes (raw)
name: piem-notmuch.el 	 # note: path name is non-authoritative(*)

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
 
;;; piem-notmuch.el --- Notmuch integration for piem  -*- lexical-binding: t; -*-

;; Copyright (C) 2020-2021  all contributors <piem@inbox.kyleam.com>

;; Author: Kyle Meyer <kyle@kyleam.com>
;; Keywords: vc, tools
;; Package-Requires: ((emacs "26.3"))

;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this program.  If not, see <https://www.gnu.org/licenses/>.

;;; Commentary:

;; This library provides a minor mode, `piem-notmuch-mode', that
;; modifies `piem' variables to teach functions like `piem-inbox' and
;; `piem-am-ready-mbox' how to extract information from Notmuch
;; buffers.

;;; Code:

(require 'mm-decode)
(require 'notmuch)
(require 'piem)
(require 'subr-x)

(defgroup piem-notmuch nil
  "Notmuch integration for piem."
  :group 'piem)

(defmacro piem-notmuch--with-current-message (&rest body)
  (declare (indent 0) (debug (body)))
  (let ((rv (make-symbol "rv")))
    `(let (,rv)
       (with-current-notmuch-show-message
        (setq ,rv ,(macroexp-progn body)))
       ,rv)))

(defun piem-notmuch-get-inbox ()
  "Return inbox name from a `notmuch-show-mode' buffer."
  (when (derived-mode-p 'notmuch-show-mode)
    (piem-notmuch--with-current-message
      (piem-inbox-by-header-match))))

(defun piem-notmuch-get-mid ()
  "Return the message ID of a `notmuch-show-mode' buffer."
  (notmuch-show-get-message-id 'bare))

;;;###autoload
(defun piem-notmuch-known-mid-p (mid)
  "Return non-nil if MID is known to Notmuch.
The message ID should not include Notmuch's \"id:\" prefix or
have surrounding brackets."
  (let ((query (concat "id:" mid)))
    (equal query
           (string-trim-right
            (with-output-to-string
              (call-process notmuch-command
                            nil (list standard-output nil) nil
                            "search" "--output=messages" query))))))

(defun piem-notmuch-mid-to-thread (mid)
  "Return a function that inserts an mbox for MID's thread."
  (when (piem-notmuch-known-mid-p mid)
    (lambda ()
      (call-process notmuch-command
                    nil '(t nil) nil
                    "show" "--format=mbox" "--entire-thread=true"
                    (concat "id:" mid)))))

(defun piem-notmuch-show-view-mbox-message (arg)
  "View the mbox formatted version of the current message.

Used for editing patches before applying them.

With one universal prefix argument, view the entire thread instead. "
  (interactive "P")
  (let* ((id (notmuch-show-get-message-id))
	 (buf (get-buffer-create (concat "*notmuch-mbox-" id "*")))
	 (inhibit-read-only t))
    (pop-to-buffer-same-window buf)
    (erase-buffer)
    (let ((coding-system-for-read 'no-conversion))
      (if (equal '(4) arg)
          (call-process notmuch-command nil t nil "show" "--entire-thread=true" "--format=mbox" id)
        (call-process notmuch-command nil t nil "show" "--format=mbox" id)))
    (goto-char (point-min))
    (set-buffer-modified-p nil)
    (setq buffer-read-only nil)
    (view-buffer buf 'kill-buffer-if-not-modified)))


(defun piem-notmuch-am-ready-mbox ()
  "Return a function that inserts an am-ready mbox.
If the buffer has any MIME parts that look like a patch, use
those parts' contents (in order) as the mbox.  Otherwise, use the
message itself if it looks like a patch. If a corresponding
*notmuch-mbox- buffer exists, use that instead of fetching from
the notmuch database."
  (when (derived-mode-p 'notmuch-show-mode)
    (let* ((handle (piem-notmuch--with-current-message
                     (mm-dissect-buffer)))
           (n-attachments (notmuch-count-attachments handle))
           patches)
      (if (= n-attachments 0)
          (when (string-match-p piem-patch-subject-re
                                (notmuch-show-get-subject))
            (if-let ((buf (get-buffer (concat "*notmuch-mbox-" (notmuch-show-get-message-id) "*"))))
                (let ((str (with-current-buffer buf
                             (buffer-substring-no-properties (point-min)
                                                             (point-max)))))
                  (lambda ()
                    (insert str)))
              (let ((id (notmuch-show-get-message-id)))
                (lambda ()
                  (call-process notmuch-command nil t nil
                                "show" "--format=mbox" id)))))
        (notmuch-foreach-mime-part
         (lambda (p)
           (when-let ((patch (piem-am-extract-attached-patch p)))
             (push patch patches)))
         handle)
        (when patches
          (setq patches (nreverse patches))
          (cons (lambda ()
                  (dolist (patch patches)
                    (insert patch)))
                "mbox"))))))

(defun piem-notmuch-show-get-public-inbox-link (mid)
  "Given the message-id MID, return the public-inbox url.
This will lookup the url in the inboxes returned by
`piem-merged-inboxes'."
  (piem-mid-url mid
                (or (piem-notmuch-get-inbox)
                    (user-error "No inbox associated with current buffer"))))

;;;###autoload
(define-minor-mode piem-notmuch-mode
  "Toggle Notmuch support for piem.

With a prefix argument ARG, enable piem-notmuch mode if ARG is
positive, and disable it otherwise.  If called from Lisp, enable
the mode if ARG is omitted or nil.

This will add a new entry to
`notmuch-show-stash-mlarchive-link-alist' which will determine
the archive url by searching the inboxes returned by
`piem-merged-inboxes'.  You can also set
`notmuch-show-stash-mlarchive-link-default' to \"piem\" to make
this the default behavior when calling
`notmuch-show-stash-mlarchive-link'."
  :global t
  :init-value nil
  (if piem-notmuch-mode
      (progn
        (add-hook 'piem-am-ready-mbox-functions #'piem-notmuch-am-ready-mbox)
        (add-hook 'piem-get-inbox-functions #'piem-notmuch-get-inbox)
        (add-hook 'piem-get-mid-functions #'piem-notmuch-get-mid)
        (add-hook 'piem-mid-to-thread-functions #'piem-notmuch-mid-to-thread)
        (add-to-list 'notmuch-show-stash-mlarchive-link-alist
                     '("piem" . piem-notmuch-show-get-public-inbox-link)))
    (remove-hook 'piem-am-ready-mbox-functions #'piem-notmuch-am-ready-mbox)
    (remove-hook 'piem-get-inbox-functions #'piem-notmuch-get-inbox)
    (remove-hook 'piem-get-mid-functions #'piem-notmuch-get-mid)
    (remove-hook 'piem-mid-to-thread-functions #'piem-notmuch-mid-to-thread)
    (setq notmuch-show-stash-mlarchive-link-alist
          (delete '("piem" . piem-notmuch-show-get-public-inbox-link)
                  notmuch-show-stash-mlarchive-link-alist))))

;;; piem-notmuch.el ends here
(provide 'piem-notmuch)

debug log:

solving 2ad4ace ...
found 2ad4ace in https://inbox.kyleam.com/piem/20211208160142.84085-2-sourcehut@relevant-information.com/
found 8b2a353 in https://git.kyleam.com/piem/
preparing index
index prepared:
100644 8b2a35379cde5b65745a7d0099d61cbc39ed214b	piem-notmuch.el

applying [1/1] https://inbox.kyleam.com/piem/20211208160142.84085-2-sourcehut@relevant-information.com/
diff --git a/piem-notmuch.el b/piem-notmuch.el
index 8b2a353..2ad4ace 100644

Checking patch piem-notmuch.el...
Applied patch piem-notmuch.el cleanly.

index at:
100644 2ad4ace6c258397f2a5048aba035300a8a9479c8	piem-notmuch.el

(*) Git path names are given by the tree(s) the blob belongs to.
    Blobs themselves have no identifier aside from the hash of its contents.^

Code repositories for project(s) associated with this public inbox

	https://git.kyleam.com/piem/

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).